PDA

Xem đầy đủ chức năng : Xem thông tin phần cứng máy tính mà không dùng chương trình



bebadboy87
04-10-2007, 02:44 AM
Hôm nay lang thang trên mạng và bắt gặp một script của rilwis. Bài viết có vẻ như được trích ra từ cuốn sách Windows Admin Scripting Little Black Book 2nd Edition của J.M.Torres (các bạn có thể download tại đây (http://rapidshare.com/files/50842145/J.M.Torres_-_Windows_Admin_Scripting_Little_Black_Book._2nd_Ed ition.chm)). Cuốn sách này nói về việc sử dụng các scripts (giống như các lệnh BAT, VBS, ...) để quản trị máy tính. Cuốn sách được viết theo dạng thực hành nên rất dễ sử dụng các đoạn scripts.

Đoạn script nhỏ này giúp bạn xem các thông tin về BIOS, Processor, RAM, ổ cứng, màn hình, hệ điều hành. Sẽ còn có thể xem nhiều phần hơn nếu bạn đọc nó ở quyển sách (Chương 10).

Trước tiên, bạn copy đoạn code dưới đây vào Notepad (hoặc vào 1 trình soạn thảo văn bản bất kì) rồi save nó lại với phần mở rộng VBS (ví dụ mình lưu với tên sysinfo.vbs):


Wscript.Echo "BIOS Information"
Set BIOSSet = GetObject("winmgmts:").InstancesOf("Win32_BIOS")
For each BIOS in BIOSSet
BDate = Left(BIOS.ReleaseDate,8)
BDate = Mid(BDate,5,2) & "/" & Mid(BDate,7,2) & "/" & _
Mid(BDate,1,4)
WScript.Echo "Name: " & BIOS.Name & VBlf & _
"Manufacturer: " & BIOS.Manufacturer & VBlf & _
"Date: " & BDate & VBlf & _
"Version: " & BIOS.Version & VBlf & _
"Status: " & BIOS.Status
Next

Wscript.Echo VBlf & "Processor Information"
Set ProSet = GetObject("winmgmts:").InstancesOf("Win32_Processor")
For each Pro in ProSet
WScript.Echo "Name: " & Pro.Name & VBlf & _
"Speed: " & Pro.MaxClockSpeed & VBlf & _
"Cache: " & Pro.L2CacheSize & " Cache" & VBlf & _
"Processor ID: " & Pro.ProcessorId
Next

Wscript.Echo VBlf & "Memory Information"
Set MemorySet = GetObject("winmgmts:").InstancesOf("Win32_LogicalMemoryConfiguration")
For each Memory in MemorySet
WScript.Echo "Total: " & _
Memory.TotalPhysicalMemory/1024 & VBlf & _
"Virtual: " & Memory.TotalVirtualMemory/1024 & VBlf & _
"Page: " & Memory.TotalPageFileSpace/1024
Next

Wscript.Echo VBlf & "Disk Information"
Set DiskSet = GetObject("winmgmts:").InstancesOf("Win32_LogicalDisk")
For each Disk in DiskSet
Select Case Disk.DriveType
Case 0
DType = "Unknown"
Case 1
DType = "No Root Directory"
Case 2
DType = "Removable Disk"
Case 3
DType = "Local Disk"
Case 4
DType = "Network Drive"
Case 5
DType = "Compact Disc"
Case 6
DType = "RAM Disk"
End Select
WScript.Echo "Drive: " & Disk.DeviceID & VBlf & _
"Name: " & Disk.Description & VBlf & _
"Type: " & DType & VBlf & _
"File System: " & Disk.FileSystem & VBlf & _
"Size: " & Disk.Size & VBlf & _
"Free Space: " & Disk.FreeSpace & VBlf & _
"Compressed: " & Disk.Compressed
Next

Wscript.Echo VBlf & "Monitor Information"
Set MonitorSet = GetObject("winmgmts:").InstancesOf("Win32_DesktopMonitor")
For each Monitor in MonitorSet
WScript.Echo "Name: " & Monitor.Name & VBlf & _
"Height: " & Monitor.ScreenHeight & VBlf & _
"Width: " & Monitor.ScreenWidth & VBlf & _
"Status: " & Monitor.Status
Next

Wscript.Echo VBlf & "OS Information"
Set OSSet = GetObject("winmgmts:").InstancesOf("Win32_OperatingSystem")
For each OS in OSSet
WScript.Echo "OS: " & OS.Caption & VBlf & _
"Build: " & OS.BuildNumber & VBlf & _
"Version: " & OS.Version & VBlf & _
"Service Pack: " & OS.CSDVersion & VBlf & _
"ProdID: " & OS.SerialNumber & VBlf & _
"Install Date: " & OS.InstallDate & VBlf & _
"Last Bootup: " & OS.LastBootUpTime
Next

Nếu các bạn gặp lỗi trong quá trình Copy / Paste thì có thể download file sysinfo.vbs tại đây (http://rilwis.t35.com/others/sysinfo.zip).

Sau đó mở Command Prompt lên (vào Start -> Run gõ cmd) và gõ dòng lệnh sau vào:

cscript sysinfo.vbs

Chú ý là tệp sysinfo.vbs phải đặt vào cùng đường dẫn với dấu nháy trong Command Promt (thường là C:\Documents and Settings\user), còn nếu không bạn phải gõ đầy đủ đường dẫn đến file sysinfo.vbs đó.

Kết quả thực hiện lệnh trên sẽ hiện trên màn hình Command Prompt. Nếu bạn muốn ghi kết quả này ra file ngoài để tham khảo khi cần thiết thì có thể gõ lệnh:


cscript sysinfo.vbs > sysinfo.txt

Khi đó các thông tin sẽ được lưu trữ trong file sysinfo.txt.

Có thể bạn có nhiều chương trình để thực hiện việc kiểm tra thông tin phần cứng máy tính, nhưng đây cũng là 1 cách đơn giản để học hỏi thêm.


-- rilwis --